(* la presente grammatica è stata generata a partire dalla grammatica http://polygen.org/web/fileadmin/grammar/ita/bio.grm *)

I ::=   "title:    Biografia di" {Nome} {[Pseudonimo]} {Cognome} "\n"
      ^ "author:   Maurizio (variazioni su bio.grm by Manta)\n"
      ^ "language: italian\n"
      ^ "status:   mature\n"
      ^ "topic:    misc\n"
      ^ "audience: anybody (ma gli amici di Mau in particolare)\n"
      ^ "disclaim:" Personaggio [non] (e' fra | fa parte de^) i (migliori|peggiori) (amici|nemici) di (Nome|Cognome)
;



S ::= ("<b>" {Nome} {[Pseudonimo]} {Cognome} "</b>")
	Nascita 
	Infanzia 
	{Tribolazioni}
	"<br/>"\
	{Affetti}
	Conquista
	"<br/>"\
	Epilogo^".";

Nome ::= "Maur" ^SecondaParte;
Cognome ::= "Man" ^SecondaParte;
Pseudonimo ::= "Gian" ^(franzo|nizzero|nozzo|mauro|"-Baptiste");
SecondaParte ::= etti | izio;

Nascita ::= (nasce | (si ritiene | si tramanda) sia nato | 
	fa la sua prima (apparizione|comparsa) | 
	appare per la prima volta) 
	{LuogoNascita}
	{TempoNascita} ^"."\;

LuogoNascita ::= (
	a \>Citta | 
	sulle alture del "Golan" | 
	nel "Laos" (occidentale|orientale) | 
	in ("Macedonia" | "Mesopotamia") | 
	nel Luogo
	);


TempoNascita ::= (
	nel 1975 | 
	nella notte dei tempi | 
	++nell'ottobre di un anno qualsiasi | 
	tra {Festa1} e {Festa2} | 
	nel \Era);


Era ::= (
	giurassico |
	precambriano |
	(paleo | neo)^litico
	);


Festa1 ::= (
	\natale |
	\befana |
	\ferragosto |
	\san \valentino
	);
	
Festa2 ::= (
	\pasqua |
	\pasquetta | 
	\capodanno |
	\carnevale |
	il 20 di ottobre [di un anno a caso]
	);


Infanzia ::= 
	[
		la sua (vita [sessuale]| esistenza) (subisce | attraversa) un (improvviso|importante|decisivo|inquietante|repentino) (cambia|muta|sconvolgi)^mento quando^","
	]
	(dopo | al termine di | in seguito a | a seguito di) 
		( un (lungo | tristo | felice | interminabile) periodo (trascorso | passato | intrapreso) |
		  una (meravigliosa | tormentata | gioiosa | lugubre) (infanzia | giov^(i|a)^nezza) (trascorsa | passata | intrapresa)
		)
	[(serena | dolorosa | travagliata | consapevol)^mente]
	{nel Luogo} {a Azione} ^", " 
	ConclusioneInfanzia;


Tribolazioni ::= (
	>Evento | il dramma che Dramma) 
	lo (costringe | obbliga | persuade | convince | spinge [definitivamente] | invoglia | muove) 
	a Costrizione^"."\;

Conquista ::= 
	{ 
		( {(riesce a ottenere | conquista | ottiene | consegue)} {[alla fine | finalmente | infine | eziandio | orsu']} Oggetto
		| (smaschera | sventa | partecipa a | organizza ) un Complotto) 
	}
	{nel TempoConquista} ^"."\;

TempoConquista ::= ( 19^AnnoTardo | 2001 | ("Rinasci" | "Risorgi")^mento );

AnnoTardo ::= (8|9)^(1|2|3|4|5|6|7|8|9);


Epilogo ::= (ancora oggi [sovente|spesso|volentieri] | 
	se ci e' concesso | 
	a tutt'oggi |
	(a noi | ci) piace dire che | 
	possiamo affermare che | 
	senza dubbio |
	certamente |
	al di la' di ogni altra considerazione) 
	lo 
	(ricordiamo|
	rimembriamo|
	commemoriamo|
	portiamo nei nostri cuori | 
	esaltiamo | 
	(>(additiamo | innalziamo) [agli occhi del mondo [intero]])) 
	Predicato.(M|F);

Predicato ::= (
	con [ ( somm^(M: o | F: a)  | grande | immens^(M: o | F: a)  ) ] 
		( F: >(gioja| allegria | osservanza | ottemperanza | sicumera | devozione | simpatia) | 
		M: >(giubilo | rispetto | ostracismo) ) | 
	(come|quale) [fulgido | eclatante | illuminante | sorprendente | raggiante | raro | eccezionale | chiaro | cangiante | altalenante | umile | sublime
			  | sommo | brillante ] 
	(esempio|--maestro|-modello) di >(virtute [et conoscenza] | 
		carita' [cristiana | musulmana | ebraica | "assiro-babilonese"]| 
		castita' [ieratica] | 
		(r|in)^ettitudine |
		cultura |
		serieta' |
		[em^]pieta' |
		 (devozione | attaccamento)
			   [ al denaro | alla vita | ai genitori | alla causa di Personaggio | al cibo
			   | al lavoro | ai valori [veri] della vita | ai sentimenti umani] | 
		(deficienza | demenza) [senile | senza possibilita' di (recupero | ricovero)] |
		devozione [a \(visnu'| krisna | manitu') | alla figa ]));

Citta ::= (gottinga | jena | mombasa | bassora | nairobi | samarcanda| damasco | ulan^"-Bator"|
	hourgada | bisceglie | tripoli | scasazza "(PA)" | trapani | macerata | katmandu | 
	montevideo | bangkog | livorno | fucecchio | zacinto | lugano |
	(robecchetto | castelletto | cassinetta) 
	(di \cuggiono | con \induno | di \lugagnano) "(MI)"
	);

Luogo ::= (
	^la >(steppa|tundra|taiga|prateria|brughiera) [Nazionalita]| 
	^l'altopiano dell'^"Atlante" |
	deserto del "Gobi"| 
	falanstero di \Citta |
	mar "Baltico" | 
	^l'orto (di suo (cugino|genero|cognato) \(astianatte| agesilao | ermenegildo| agamennone) | botanico) | 
	(cortile | parco | loggiato) della facolta' di Materia [dell'universita' [degli stu^[pi]^di] di \Citta]);

Azione ::= ((allevare | addestrare | -clonare) 
		>(caimani | 
		optopteri | 
		varani [di "Komodo"] | 
		arpie | 
		moffette |
		manguste [nane] |
		fenici | 
		pernici [bulgare] | 
		pidocchi [armeni] | 
		pirana [del "Baltico"]) [da (passeggio | guardia | compagnia)] | 
	(coltivare | spacciare | -sniffare)
		>(marijuana | 
		oppi^ >(o|acei) | 
		cocaina | 
		mango e papaya |
		piante carnivore [transgeniche]) | 
	(incendiare | dare alle fiamme | saccheggiare | devastare)
		>(esercizi commerciali [bulgari] | 
		villaggi (turchi| curdi | mongoli | afghani) | 
		chiese [ortodosse | bizantine | romaniche] | 
		moschee | 
		musei 
		) | 
	(violent|stupr|brutalizz)^are 
		>(vacche cipriote | 
		vecchiette | 
		zingare | 
		caimani | 
		galline | 
		pecorai slavi | 
		crotali curdi | 
		[simpatici] pastori armeni) |
	collezionare
		>(foto che ritraggono Personaggio | 
		nani da giardino |
		poesie in lingua Nazionalita |
		cellulari usati) |
	forgiare (sesterzi | daghe romane | missili scud | museruole in tungsteno | braghe di fustagno [da palombaro]) |
	(irrompere | progettare l'irruzione) in un bagno a "Cagliari" |
	(mangiare | ingozzarsi di | nutrirsi di | cucinare) Cibo |
	movimentare poponi
	)(_|--- e Azione)	
;


Perdita ::= 
	(^la verginita' [anale | podale | [m^]ascellare] | 
	menisco [ambi^]destro |
	^l'orientamento | 
	suo fascino (carismatico | massonico ) |
	suo {"savoir-faire"} {discreto} |
	suo sapor "medio-orientale" |
	(cane|gatto|criceto) NomeAnimale | 
	(pozzo petrolifero | ^l'impianto petrolchimico) a lui caro | 
	(^l'autobus | treno | tram) "("^causa ritardo^")" );

NomeAnimale ::= ("P" | "F" | "B") ^ (i | o | e) ^ (g | d | b | d | f | p) ^ (i | o);

Caduta ::= (
	^l capezzolo Parte | 
	^llo zigomo Parte | 
	^l muro di "Berlino" | 
	^ll'impero ("Ottomano" | "Bizantino" | "Curdo") | 
	^i peli (pubici | ascellari | pettorali) | 
	^lle orecchie | 
	^l bicchiere di mano | 
	^l sopracciglio Parte | 
	^lla dinastia ("Ming"|"Berlusconi"|"Romanov"|carolingia) );

Parte ::= (destro|sinistro);

ConclusioneInfanzia ::= 
	(lascia i luoghi (natali|++natii|(m|p)^aterni|d'origine) | 
	abbandona il (t|l)^etto (coniugale|(m|p)^aterno) | 
	--si (taglia|mangia|divora) (le unghie|i calli) (dei|di ambo i) piedi | 
	(compie | commette| intraprende) FolleGesto) 
	per (>(recarsi | approdare | andare a vivere) a | raggiungere | conquistare | saccheggiare | mettere (a soqquadro|a ferro e fuoco| igni ferrique))  \Citta^"," dove (
		{(studia [Avverbio]|frequenta [Avverbio] un corso di) Materia} {per Tempo} |
		(compie | commette| intraprende) FolleGesto |
		{(>(si dedica | decide di consacrarsi | passa il suo tempo | si impegna) a | si occupa di) Azione} 
		{per Tempo} |
		si converte [(improvvisa|inaspettata)^mente | a seguito di un (trauma psichico | evento folgorante | incidente a Incidente)] a Religione
		) 
	^"."\;

Incidente ::= (^l c^(a|o)^llo del piede | ^l coglione ambidestro | ^ll'unghia incarnita);

Religione ::= (^l (buddh|tao|^lo shinto)^ismo |
		^ll'^((islam|ebra)^ismo) |
		^l cristianesimo bizantino| 
		^l cattocomunismo | 
		^l confucianesimo |
		^ll'adorazione >(del dio "Shiva"| dei pitoni | del bromuro) | 
		^l brahamanesimo |
		^l bolscevismo | 
		^lla cucina (transgenica|macrobiotica|Nazionalita) |
		^ll'open source
		);


Dramma ::= (
	lo segnera' >(per sempre | per Tempo) | 
	ricordiamo tutti con (sgomento|tormento|simpatia|sagacia) | 
	lo >(affligge | affatica | sgomenta)
	) "("^ Evento ^")";


Evento ::= la [improvvisa | devastante | inattesa]
		>(perdita del Perdita | caduta de Caduta | rottura Rottura) |
	l'incidente a Incidente |
	((lo | il terribile) scontro [finale] | (il [tragico]|l'acerrimo) duello) tra Personaggio e Personaggio |
	il suo incontro con Personaggio |
	Malattia |
	la partecipazione a un Complotto 
;


Rottura ::= (del salvadanaio | 
	con la ["ex-"^] (moglie | ragazza) | 
	delle tubature del ([termo^]syfone | riscaldamento | cesso) |
	del sedile dell'auto | 
	con Personaggio |
	della sua [amata] carriola [da (edilizia | giardinaggio)]
             );

Malattia ::= (l'insorgenza (delle emorroidi | 
			del >(catarro [verde assassino]|
			cimurro|
			^la forfora |
			^la calvizie precoce | 
			morbo della mucca pazza |
			prolasso delle gonadi |
			bicazzo monopalla |
			singhiozzo [spastico]
				)|
			dei brufoli)
		| un attacco di  >(febbre gialla | 
			prostatite |
			dissenteria |
			letargia acuta |
			peste [bubbonica|nera])
		);

Costrizione ::= (
	(stabilirsi [per Tempo]| emigrare | fuggire [entro Tempo] | andare a vivere [per Tempo]) a \Citta | 
	Azione |  
	(compiere|commettere|intraprendere) FolleGesto);


Oggetto ::= (
	(la laurea | il diploma | il tirocinio) in Materia | 
	(l'agognato | il tanto >(atteso|desiderato) | l'ambito | il prestigioso) 
	(
		rapporto sessuale [anale] con BellaFica | 
		riconoscimento di status di (
			terrone | 
			(prigioniero | rifugiato) politico | 
			studente lavoratore | 
			fricchettone | 
			tamarro | 
			(burino | buzzurro | zotico) [totale | a tutto tondo]) 
			[da parte del (
				^lo "Stato" | 
				(^l'amministrazione comunale | consiglio provinciale) di \Citta | 
				"Dalai Lama" )] |
 	(mestiere | posto fisso| apprendistato | contratto di "co.co.co" per l'attivita') di (
			scafista | becchino | pulitore di cessi | operatore analogico | spazzolascroti | assaggiatore di Cibo
			)
	)		
	); 

Materia ::=  (	
		(topo | fenomeno | psico | filo | mito | astro | traumato | tossico )^logia 
		(del >(^la topa | carciofo | ramarro [nano [alato]]) | 
			romanza | anonima | traumatica | Nazionalita ) 
		[applicata alle macchine [agricole]] |
		[kundalini | hatha] yoga |
		lingua [e letteratura] Nazionalita |
		missilistica | 
		sesso tantrico |
		tecnica agraria avanzata |
		borseggio acrobatico |
		frittura con l'acqua | 
		giocoleria (meditativa|computazionale) |
		web (design | marketing)
		)			

;


Complotto ::= complotto Suff[^"-"^Suff]^"-"^Finalecomp [guidato da Personaggio] [(ai danni del^| contro) (l'amministrazione comunale di \Citta | la nazione \Nazionalita)];

Suff ::= +++pluto | +++catto | +++anarco | +++bolscevo | anti | post | retro | etno | copto | pluri | agri^[colo] | proto | pseudo;

Finalecomp ::= comunista | femminista | bolscevico | giudaico | insurrezionista | irredentista | maoista | marxista | leninista | "marxista-leninista" | fascista | capitalista | islamico | sionista | "cattolico-integralista";



Affetti ::= [( particolarmente | assai | decisamente | inspiegabilmente | piuttosto | incredibilmente )
             [s^]fortunato
             ( nei sentimenti | nei legami sentimentali | negli affetti | nelle questioni di cuore | in amore)^","
			]
			
			(
            {(conosce | incontra)} {Dove}
            ( (la donna | l'amore) della sua vita
            | una [giovane [e bella]] (ragazza | donna) Nazionalita [di \Citta | di Numero anni]
            ) ^"," 
            ( che ( sposera' a \Citta
                  | ((gli insegna (a | l'arte di) | lo (convince|spinge) a) Azione | --lo converte a Religione)
                  | rapisce deportandola nel Luogo
                  )
            | con la quale (si trasferisce | va a vivere | scappa | fugge | si ritira)
              (nel Luogo | a \Citta)
            )
            [e (con la quale dara' alla luce | che gli donera')  Figlio
             [e poi ancora Figlio ]] 
			
			| 
			 
			({si scopre ( >(omo|bi|tran|tri|etero|mono|penta)^sessuale | uomo | donna)}
             {(a soli | ad appena | quando raggiunge i | al compiere dei) Numero anni }
             {[dopo un (travagliato | intenso | terribile) conflitto interiore]})
            e (scappa | fugge) (di casa | da [^lla sua [amata]] \Citta) 
			per ritirarsi nel Luogo
             [in compagnia (di un uomo | di una donna ) [che aveva conosciuto [nel TempoConquista]
              (durante un viaggio a \Citta| nel Luogo)]]
			  )  ^"."\;



Dove ::= al cinema[^tografo] | in discoteca | al bowling | al teatro [comunale] di \Citta | in crocera
      |  ad una festa (di compleanno | di \Festa1) | alla gita di \pasquetta 
	  | al circo | alla ["Santa"] messa [di \Festa1]| all'oratorio | in carcere
      |  in autobus | in corriera | al bar | in stazione | su internet [in chat];


Figlio ::= (un [simpatic^[issim^]o] figlio (nano | obeso | demente | terrorista | gobbo) | 
	una [simpatica] figlia (obesa | anoressica | barbuta | musulmana | gobba) | 
	Numero gemelli [(etero|mono)^zigoti]);


Nazionalita ::= bulgara | irachena | rumena | cinese | paraguayana | uruguayana | turca
             |  ostrogota | unna | svizzera | bergamasca | nipponica | aborigena | tibetana
	     |  ugandese | pakistana | siberiana | aretina | etrusca | russa | lappone | sioux
	     |  (nuit | eschimese) | costaricana | portoricana | peruviana | mal^[t^]ese
	     |  sarda | curda | lucana | calabra | sicula | cilena | micronesiana | azerbaijana | cecena;


Tempo ::= Numero Unita;

Unita ::= settimane | mesi | giorni | ore | minuti | secondi | decenni | ere geologiche | nanosecondi | stagioni;

Numero ::= Cifra ( _ | ++^Cifra);

Avverbio ::= con >(
			malcelato stupore|
			dis^(incanto|interesse) | 
			devozione | 
			trasporto | 
			passione) |
		^"," per >(
			gioco | 
			divertimento | 
			sconfiggere (la noia | l'emicrania | le emorroidi)
			)^",";

Cifra ::= 2|3|4|5|6|7|8|9;

Personaggio ::= "Saddam Houssein" | 
		"Madre Teresa di Calcutta" |
		"Bin Laden" |
		l'uomo "Del Monte" |
		il subcomandante "Marcos" |
		il "Papa" |
		il "Dalai Lama" |
		"Linus Torvald" |
		"Bill Gates" |
		"Brad Pitt" |
		"Paolo Limiti" |
		"Gigi Marzullo" |
		se stesso |
		"Catilina" | 
		"Cicerone" | 
		("Elio" | il) "Gioanola" |
		(il vigile | l'omino) del pennello "Cinghiale";

BellaFica ::=   "Pamela Anderson" | 
		"Paola Barale" |
		"Tania Russof" | 
		"Maria Teresa Ruta" | 
		"Rosy Bindi" | 
		"Milly Carlucci" | 
		"Letizia Moratti" |
		"Alessia " >("Marcuzzi" | "Merx") |
		il ministro per gli affari pub^[bl]^ici;


FolleGesto ::=  (il folle | l'insano | l'^>(inspiega|ingiustifica|esecra|igno)^bile) (gesto|atto|cimento) di (
	giocare una schedina con tutti 2 | 
	radersi le ascelle | 
	installare "Windows XP" |
	ruttare a tavola |
	sodomizzare uno struzzo transgenico | 
	(mangiare | cucinare) un (piatto | paio di piatti | bel po' di piatti) di Cibo | 
	imparare la lingua Nazionalita |
	partecipare al festival canoro di \Citta ["(vincendolo)"] |
	comprare un dipinto di arte Nazionalita |
	(partecipare | sventare) un Complotto |
	pedalare in retromarcia | 
	assumere cibalgina [via endovenosa] | 
	iscriversi a un torneo di (freccette|trincetto) | 
	++leggere ("'Va dove ti porta il cuore'" | 
		la biografia di un personaggio (quale|come) Personaggio | 
		"'Il Corano for Dummies'" |
		"'1001 modi di cagare controvento'")
	);

Cibo ::= ( riso[^tto] | lenticchie | pizza | fichi | krauti | pandoro | panettone
         | mandorlato | cioccolata | uvetta | insalata [di Cibo] | rognoni | gelato
         | budella | trippa | sarde | uova | pasta | cozze | porri | cavolfiore 
         )  
         Cottura
;

Cottura ::= in rosso | ai ferri | alla piastra | in salmi' | in umido | al sugo | al forno
         |  in bagnomaria | in decotto | in camicia | al dente | al burro | alla diavola
         |  sotto (sale | pepe | aceto | ^lio | vuoto)
;